Actualmente estoy programando un rexx que me permita saber el consumo actual de MSU de mi sistema así como el 4HRA. Hasta ahora he logrado:
- Obtener el Sysname
- Obtener el modelo y tipo
- Capacidad definida de MSU's para la Lpar
- 4HRA
- Y saber si la Lpar esta capped o no
El rexx no me lo he inventado yo, he tomado fragmentos de varios sitios en donde al final todos leen la Resource Control Table.
Sin embargo, hay un dato que me gustaría conocer pero no he encontrado como extraerlo por ningún lado y es el número de MSU's activas (en uso) en ese momento. El dato que necesito es el que aparece en la columna "MSU Act" del panel CPC Capacity de la opción 3>3 del Monitor III de RMF.
Con esto, la pregunta concreta sería ¿cómo conocer el numero de MSU's actuales de una partición?
Como apoyo a para ayudar a otros, comparto el rexx que actualmente estoy usando:
Código: Seleccionar todo
/* REXX */
/* Trace ?r */
/*********************************************************************/
CVT = C2d(Storage(10,4)) /* point to CVT */
RMCT = C2d(Storage(D2x(CVT+604),4)) /* point to RMCT */
RCT = C2d(Storage(D2x(RMCT+228),4)) /* Resource Control Tbl */
RMCTCCT = C2d(Storage(D2x(RMCT+4),4)) /* cpu mgmt control tbl */
CCVUTILP = C2d(Storage(D2x(RMCTCCT+102),2)) /* CPU Utilization */
RCTLACS = C2d(Storage(D2x(RCT+196),4)) /* 4 hr MSU average */
RCTIMGWU = C2d(Storage(D2x(RCT+28),4)) /* Image defined MSUs */
RCTCECWU = C2d(Storage(D2x(RCT+32),4)) /* CEC MSU Capacity */
/*********************************************************************/
/* The CPU model is stored in packed decimal format with no sign, */
/* so to make the model printable, it needs to be converted back */
/* to hex. */
MODEL = C2d(Storage(D2x(CVT - 6),2)) /* point to cpu model */
MODEL = D2x(MODEL) /* convert back to hex */
/*********************************************************************/
CURRDATE = Date('S')
CURRTIME = Time()
SYSNAME = MVSVAR('SYSNAME')
CAPPED = 'N'
PERCENT = Format((RCTLACS/RCTIMGWU)*100,3,2)
If RCTLACS <> 0 then do
If RCTLACS >= RCTIMGWU & RCTIMGWU <> RCTCECWU then ,
CAPPED = 'Y'
End
say SYSNAME CURRDATE CURRTIME,
'CpuModel='MODEL,
'MSU='RCTIMGWU,
'CPU_Utyl='CCVUTILP'%',
'4HRA='RCTLACS,
'Limit='PERCENT'%',
'Capp?='CAPPED
